# externals.pri
# Sets up the include and library directories for external dependencies

# If you want to manually set the external path, uncomment the following line
# EXTERNALDIR = /path/to/externals

# Test if enviromental variable for externals is set

isEmpty(EXTERNALDIR) {
    EXTERNALDIR = $$(VATSIM_EXTERNAL_DIR)
}

# if no env variable is set, we use the standard path in the client folder.
isEmpty(EXTERNALDIR) {
    EXTERNALDIR = $$TOPSRCDIR/externals
}

# Test the folder if it exists and has a include subfolder
!exists("$$EXTERNALDIR/include") {
    error("Could not find externals in $$EXTERNALDIR. Please install it!")
}

# Everything is fine. Add the include path
INCLUDEPATH *= $$EXTERNALDIR/include

# and the library path depending on the used compiler
win32-msvc2010 {
    equals(WORD_SIZE,64): LIBS *= -L$$EXTERNALDIR/vs2010_64/lib
    equals(WORD_SIZE,32): LIBS *= -L$$EXTERNALDIR/vs2010_32/lib
    equals(WORD_SIZE,32): LIBS += -luser32
}
win32-msvc2013 {
    equals(WORD_SIZE,64): LIBS *= -L$$EXTERNALDIR/vs2013_64/lib
    equals(WORD_SIZE,32): LIBS *= -L$$EXTERNALDIR/vs2013_32/lib
    equals(WORD_SIZE,32): LIBS += -luser32
}
win32-g++ {
    equals(WORD_SIZE,64): LIBS *= -L$$EXTERNALDIR/mingw64/lib
    equals(WORD_SIZE,32): LIBS *= -L$$EXTERNALDIR/mingw32/lib
    LIBS += -luser32
}
linux-g++* {
    equals(WORD_SIZE,64): LIBS *= -L$$EXTERNALDIR/linux64/lib
    equals(WORD_SIZE,32): LIBS *= -L$$EXTERNALDIR/linux32/lib
}
macx-clang {
    equals(WORD_SIZE,64): LIBS *= -L$$EXTERNALDIR/macx-clang64/lib -F$$EXTERNALDIR/macx-clang64/lib
    equals(WORD_SIZE,32): LIBS *= -L$$EXTERNALDIR/macx-clang32/lib -F$$EXTERNALDIR/macx-clang32/lib
}
