mirror of
https://github.com/swift-project/pilotclient.git
synced 2026-03-22 23:05:36 +08:00
f63008dd3f
This aligns the behavior and concept with the 32 bit FSX version. SimConnect is loaded at runtime, depending on the version being selected. It also adds a featuren to change the P3D SimConnect version at runtime by unloading the previous and loading a new one. ref T349
82 lines
1.7 KiB
Plaintext
82 lines
1.7 KiB
Plaintext
LIBS *= -L$$DestRoot/lib
|
|
|
|
unix:!macx {
|
|
# Set the rpath-link to find dependent shared libraries when linking
|
|
# Note: This does not add any rpath into the binaries.
|
|
LIBS += -Wl,-rpath-link,$$DestRoot/lib -Wl,-rpath-link,$$[QT_INSTALL_LIBS]
|
|
}
|
|
|
|
simulatorfsxcommon {
|
|
addStaticLibraryDependency(simulatorfsxcommon)
|
|
LIBS += -lsimulatorfsxcommon
|
|
}
|
|
|
|
simulatorfscommon {
|
|
addStaticLibraryDependency(simulatorfscommon)
|
|
LIBS += -lsimulatorfscommon
|
|
}
|
|
|
|
simulatorplugincommon {
|
|
addStaticLibraryDependency(simulatorplugincommon)
|
|
LIBS += -lsimulatorplugincommon
|
|
}
|
|
|
|
fsuipc {
|
|
addStaticLibraryDependency(fsuipc)
|
|
LIBS += -lfsuipc
|
|
}
|
|
|
|
simconnect {
|
|
DEFINES += SIMCONNECT_H_NOMANIFEST
|
|
equals(WORD_SIZE,64) {
|
|
INCLUDEPATH *= $$EXTERNALSROOT/common/include/simconnect/P3D-v4
|
|
DEFINES += P3D_SDK_VERSION=400
|
|
}
|
|
equals(WORD_SIZE,32) {
|
|
INCLUDEPATH *= $$EXTERNALSROOT/common/include/simconnect/FSX-XPack
|
|
}
|
|
|
|
RC_FILE = $$SourceRoot/src/plugins/simulator/fsxcommon/simconnect.rc
|
|
}
|
|
|
|
blackgui {
|
|
addLibraryDependency(blackgui)
|
|
LIBS *= -lblackgui
|
|
}
|
|
|
|
blackcore {
|
|
addLibraryDependency(blackcore)
|
|
LIBS *= -lblackcore -lvatlib
|
|
}
|
|
|
|
blacksound {
|
|
LIBS *= -lblacksound
|
|
}
|
|
|
|
blackinput {
|
|
addLibraryDependency(blackinput)
|
|
LIBS *= -lblackinput
|
|
|
|
macx {
|
|
LIBS += -framework CoreFoundation -framework ApplicationServices -framework Foundation -framework AppKit
|
|
}
|
|
|
|
win32 {
|
|
LIBS *= -ldxguid -lole32 -ldinput8 -lUser32
|
|
}
|
|
}
|
|
|
|
blackmisc {
|
|
addLibraryDependency(blackmisc)
|
|
LIBS *= -lblackmisc
|
|
|
|
win32 {
|
|
LIBS *= -lShell32
|
|
}
|
|
}
|
|
|
|
blackconfig {
|
|
addStaticLibraryDependency(blackconfig)
|
|
LIBS *= -lblackconfig
|
|
}
|