mirror of
https://github.com/swift-project/pilotclient.git
synced 2026-03-22 23:05:36 +08:00
44 lines
1.3 KiB
INI
44 lines
1.3 KiB
INI
load(common_pre)
|
|
|
|
TEMPLATE = lib
|
|
CONFIG += staticlib
|
|
CONFIG -= qt
|
|
|
|
OTHER_FILES += Doxyfile.qmake
|
|
OTHER_FILES += src/*.dox
|
|
OTHER_FILES += src/wiki/*.dox
|
|
|
|
win32: DOXYGEN_BIN = $$system($$(SYSTEMROOT)\system32\where doxygen 2> nul)
|
|
else: DOXYGEN_BIN = $$system(which doxygen 2> /dev/null)
|
|
|
|
!isEmpty(DOXYGEN_BIN) {
|
|
DOXYFILE = Doxyfile.qmake
|
|
QDOC_PATH = $$(QDOC_PATH)
|
|
DOXY_INPUT = .
|
|
win32-g++ {
|
|
doxy.commands = set DOXY_SRC_ROOT=$$SourceRoot &
|
|
isEmpty(QDOC_PATH): doxy.commands += set QDOC_PATH=$$[QT_INSTALL_DOCS] &
|
|
doxy.commands += doxygen $$PWD/$$DOXYFILE
|
|
}
|
|
else:win32 {
|
|
doxy.commands = set DOXY_SRC_ROOT=$$SourceRoot &
|
|
isEmpty(QDOC_PATH): doxy.commands += set QDOC_PATH=$$[QT_INSTALL_DOCS] &
|
|
doxy.commands += doxygen $$PWD\\$$DOXYFILE
|
|
}
|
|
else {
|
|
doxy.commands = DOXY_SRC_ROOT="$$SourceRoot"
|
|
isEmpty(QDOC_PATH): doxy.commands += QDOC_PATH="$$[QT_INSTALL_DOCS]"
|
|
doxy.commands += doxygen $$PWD/$$DOXYFILE
|
|
}
|
|
|
|
doxy.CONFIG = no_link target_predeps
|
|
doxy.depends = $$PWD/$$DOXYFILE
|
|
doxy.input = DOXY_INPUT
|
|
doxy.name = DOXY
|
|
doxy.output = html/index.html
|
|
|
|
QMAKE_EXTRA_COMPILERS += doxy
|
|
}
|
|
|
|
load(common_post)
|